gusucode.com > 耐品图片管理系统 标准版A > 耐品图片管理系统 标准版A/Admin_Update.asp

    <!--#include file="Inc/clsSetting.asp"-->
<!--#include file="Inc/clsMain.asp"-->
<!--#include file="Inc/clsBehind.asp"-->
<!--#include file="Inc/MD5.asp"-->
<!--#include file="Api/Api_Config.asp"-->
<%
'===============================================================
' 著作权号：中国国家版权局著作权登记号2004SR07385
' 版权所有：深圳市耐品科技开发有限公司 www.naipin.com
' 联系电话：0755-26611119　81234844　81234845
' 联系手机：13316911914
' 联系邮箱：naipin@naipin.com
'===============================================================

On Error Resume Next
Dim Rs,Rs1,ClassName,SpecialName
Dim DateString,DataType,Syskey
Dim RegionTime(2),AddTime

Set Netout = New Netout_Photo

Syskey = Request.QueryString("Syskey")
DataType = Request.QueryString("DataType")

If UCase(Syskey)<>UCase(Api_Syskey) Then
	XmlHeader()
	Response.Write("<Error>请求数据验证不通过，请与管理员联系。</Error>")
	Response.End()
End If

Select Case DataType
Case "Photo"
	AddTime = Request.QueryString("AddTime")
	If Instr(AddTime,",") Then
		AddTime = Split(AddTime,",")
		For i = 0 To 1
			RegionTime(i) = AddTime(i)
			If Not IsDate(RegionTime(i)) Then
				IF i = 0 Then
					RegionTime(0) = DateString(7)&"2000-01-01"&DateString(7)
				Else
					RegionTime(1) = DateString(0)
				End If
			Else
				RegionTime(i) = DateString(7)&RegionTime(i)&DateString(7)
			End If
		Next
	Else
		RegionTime(0) = AddTime
		If Not IsDate(RegionTime(0)) Then
			RegionTime(0) = DateString(7)&"2000-01-01"&DateString(7)
		Else
			RegionTime(0) = DateString(7)&RegionTime(0)&DateString(7)
		End If
		RegionTime(1) = DateString(0)
	End If
	
	GetTitle()
Case "Config"
	GetConfig()
Case "Synchronize"
	SetAcceptUrl()
Case "Space"
	SetLimitSize()
Case "Send"
	SetSendFlag()
Case "Region"
	GetTimeRegion()
Case Else
End Select

Set Config = Nothing
Set Netout = Nothing

Function XmlHeader()
	With Response
		.Clear
		.ContentType = "text/xml"
		.CharSet = "gb2312"
		.Expires = 0
		.Write "<?xml version=""1.0"" encoding=""gb2312""?>"&vbNewLine
	End With
End Function

Sub GetTimeRegion()
	Dim List,Rs,TimeB,TimeE
	
	XmlHeader()
	
	TimeB = Netout.FormatTime(Now(),"YYYY-MM-DD")
	TimeE = TimeB
	
	Set Rs = Server.CreateObject("adodb.recordset")
	Rs.Open "Select Max(AddTime),Min(AddTime) From Nt_title",Conn,1,1
	If Not(Rs.Eof Or Rs.Bof) Then
		If IsDate(Rs(1)) Then TimeB = Netout.FormatTime(Rs(1),"YYYY-MM-DD")
		If IsDate(Rs(0)) Then TimeE = Netout.FormatTime(Rs(0),"YYYY-MM-DD")
	End If
	Rs.Close
	Set Rs = Nothing
	
	List = "<TimeRegion><TimeB>"&TimeB&"</TimeB><TimeE>"&TimeE&"</TimeE></TimeRegion>"
	
	Response.Write(List)
	
End Sub

Sub GetTitle()
	Dim List,Rs,Rs1,Sql,ClassName,SpecialName
	
	XmlHeader()
	
	List = "<PhotoList>"
	
	Set Rs = Server.CreateObject("adodb.recordset")
	Set Rs1 = Server.CreateObject("adodb.recordset")
	
	Sql = "Select ClassId,SpecialId,TitleId,TitleUser,TitleDesc,TitleName,ManuName,ImageLocal,Copyright,IsMaitu,AcceptMaitu,AddTime from Nt_title "&_
		"Where DateDiff("&DateString(6)&",AddTime,"&RegionTime(0)&")<=0 And DateDiff("&DateString(6)&",AddTime,"&RegionTime(1)&")>=0 "&_
		"Order by titleID"
	Rs.Open Sql,Conn,1,1
	Do While Not Rs.eof
		ClassName = GetLongClassName(Rs("ClassId"),"/")
		SpecialName = GetSpecialName(Rs("SpecialId"))
		
		List = List & "<TitleInfo TitleId="""&Rs("TitleId")&""" TitleName="""&Rs("TitleName")&""" ClassName="""&ClassName&""" SpecialName="""&SpecialName&""" ManuName="""&Rs("ManuName")&""" ImageLocal="""&Rs("ImageLocal")&""" Copyright="""&Rs("Copyright")&""" IsMaitu="""&Rs("IsMaitu")&""" AcceptMaitu="""&Rs("AcceptMaitu")&""" AddTime="""&Netout.FormatTime(Rs("AddTime"),"YYYY-MM-DD HH:NN:SS")&""">"
		List = List & "<TitleDesc><![CDATA["&Rs("TitleDesc")&"]]></TitleDesc>"
		
		List = List & "<AddUser Name="""&Rs("TitleUser")&""""
		Rs1.Open "Select ID,TrueName,ManuName,UserEmail,Phone,Mobile from Nt_User Where UserName='"&Rs("TitleUser")&"'",Conn,1,1
		If Not Rs1.Eof Then
			List = List & " UserId="""&Rs1("ID")&""" TrueName="""&Rs1("TrueName")&""" ManuName="""&Rs1("ManuName")&""" Email="""&Rs1("UserEmail")&""" Phone="""&Rs1("Phone")&""" Mobile="""&Rs1("Mobile")&""">"
		Else
			List = List & " UserId=""0"">"
		End If
		Rs1.Close
		List = List & "</AddUser>"
		
		Rs1.Open "Select * from Nt_ImgBook where titleID="&Rs("TitleId"),Conn,1,1
		Do While Not Rs1.Eof
			List = List & "<ImageList ImageId="""&Rs1("Id")&""" Passed="""&Rs1("Passed")&""" AddTime="""&Netout.FormatTime(Rs1("AddTime"),"YYYY-MM-DD HH:NN:SS")&""">"
			List = List & "<ImageFile>"&Rs1("ImageFile")&"</ImageFile>"
			List = List & "<ImageInfo><![CDATA["&Rs1("ImageInfo")&"]]></ImageInfo>"
			List = List & "<ImageSize>"&Rs1("ImageSize")&"</ImageSize>"
			List = List & "<ImageDesc><![CDATA["&Rs1("ImageDesc")&"]]></ImageDesc>"
			List = List & "<Keyword><![CDATA["&Rs1("Keyword")&"]]></Keyword>"
			List = List & "<DiskPath><![CDATA["&Rs1("DiskPath")&"]]></DiskPath>"
			List = List & "<PhotoAddress><![CDATA["&Rs1("PhotoAddress")&"]]></PhotoAddress>"
			List = List & "<KeywordClass><![CDATA["&Rs1("KeywordClass")&"]]></KeywordClass>"
			List = List & "<Portrait><![CDATA["&Rs1("Portrait")&"]]></Portrait>"
			List = List & "<ProvideSize><![CDATA["&Rs1("ProvideSize")&"]]></ProvideSize>"
			List = List & "<Resolution><![CDATA["&Rs1("Resolution")&"]]></Resolution>"
			List = List & "<ImageType><![CDATA["&Rs1("ImageType")&"]]></ImageType>"
			List = List & "<ImageProperty><![CDATA["&Rs1("ImageProperty")&"]]></ImageProperty>"
			List = List & "<ShowMeaning><![CDATA["&Rs1("ShowMeaning")&"]]></ShowMeaning>"
			List = List & "</ImageList>"
			Rs1.MoveNext
		Loop
		Rs1.Close
		
		List = List & "</TitleInfo>"
		
		Rs.Movenext			
	Loop
	Rs.Close
	List = List & "</PhotoList>"
	
	Response.Write(List)
	
	Set Rs1 = Nothing
	Set Rs = Nothing
End Sub

Sub GetConfig()
	Dim List
	
	XmlHeader()

	List = "<Config>"
	List = List & "<SiteName>"&Config.SiteName&"</SiteName>"
	List = List & "<SiteUrl>"&Config.SiteUrl&"</SiteUrl>"
	List = List & "<ImagePath>"&Config.ImagePath(0)&","&Config.ImagePath(1)&","&Config.ImagePath(2)&"</ImagePath>"
	List = List & "<UserName>"&Config.UserName&"</UserName>"
	List = List & "<UserUnit>"&Config.UserUnit&"</UserUnit>"
	List = List & "<UserCard>"&Config.UserCard&"</UserCard>"
	List = List & "<UserEmail>"&Config.UserEmail(0)&"</UserEmail>"
	List = List & "<UserPhone>"&Config.UserPhone(0)&"-"&Config.UserPhone(1)&"</UserPhone>"
	List = List & "<UserMobile>"&Config.UserPhone(3)&"</UserMobile>"
	List = List & "<UserOicq>"
	For i = 0 To Ubound(Config.UserOicq)
		List = List & Config.UserOicq(i) & ","
	Next
	List = List & "</UserOicq>"
	List = List & "<Source>"&Config.Settings(0)&"</Source>"
	List = List & "<AspJpeg>"&Config.WaterMark(0)&"</AspJpeg>"
	List = List & "<WaterType>"&Config.WaterMark(2)&"</WaterType>"
	List = List & "<SoftVersion>"&Config.SoftInfo(1)&"</SoftVersion>"
	List = List & "<AgentNumber>"&Config.SoftInfo(7)&"</AgentNumber>"
	List = List & "<SiteSize>"&Netout.GetFolderSize(".")&"</SiteSize>"
	List = List & "</Config>"
	
	Response.Write(List)
End Sub

Sub SetAcceptUrl()
	Dim Rs,SoftInfo
	Address = Trim(Request.QueryString("Address"))
	
	SoftInfo = Config.SoftInfo(0)
	For i = 1 To 7
		SoftInfo = SoftInfo & "," & Config.SoftInfo(i)
	Next
	SoftInfo = SoftInfo & "," & Address
	If Right(SoftInfo,1)<>"/" Then SoftInfo = SoftInfo & "/"
	
	Set Rs = Server.CreateObject("adodb.recordset")
	Rs.Open "Select SoftInfo From Nt_Config",Conn,1,3
	Rs("SoftInfo") = SoftInfo
	Rs.Update
	Rs.Close
	Set Rs = Nothing
	
	Application.Lock()
	Application("SoftInfo") = Split(SoftInfo,",")
	Application.UnLock()
	
	With Response
		.Write("document.write('<b>更新")
		If Err Then
			.Write("失败")
		Else
			.Write("成功")
		End If
		.Write("</b>');")
	End With
End Sub

Sub SetLimitSize()
	Dim Rs,Settings,iSize
	iSize = Trim(Request.QueryString("Size"))
	
	Settings = Config.Settings(0)
	For i = 1 To 25
		Settings = Settings & "," & Config.Settings(i)
	Next
	Settings = Settings & "," & iSize
	For i = 27 To 30
		Settings = Settings & "," & Config.Settings(i)
	Next
	
	Set Rs = Server.CreateObject("adodb.recordset")
	Rs.Open "Select Settings From Nt_Config",Conn,1,3
	Rs("Settings") = Settings
	Rs.Update
	Rs.Close
	Set Rs = Nothing
	
	Application.Lock()
	Application("Settings") = Split(Settings,",")
	Application.UnLock()	
	
	With Response
		.Write("document.write('<b>更新")
		If Err Then
			.Write("失败")
		Else
			.Write("成功")
		End If
		.Write("</b>');")
	End With
End Sub

Sub SetSendFlag()
	Dim Rs,Settings,SendFlag
	SendFlag = Trim(Request.QueryString("SendFlag"))
	
	Settings = Config.Settings(0)
	For i = 1 To 26
		Settings = Settings & "," & Config.Settings(i)
	Next
	Settings = Settings & "," & SendFlag
	For i = 28 To 30
		Settings = Settings & "," & Config.Settings(i)
	Next
	
	Set Rs = Server.CreateObject("adodb.recordset")
	Rs.Open "Select Settings From Nt_Config",Conn,1,3
	Rs("Settings") = Settings
	Rs.Update
	Rs.Close
	Set Rs = Nothing
	
	Application.Lock()
	Application("Settings") = Split(Settings,",")
	Application.UnLock()	
	
	With Response
		.Write("document.write('<b>更新")
		If Err Then
			.Write("失败")
		Else
			.Write("成功")
		End If
		.Write("</b>');")
	End With
End Sub

Function GetLongClassName(ClassId,char)
	Dim Rs,i
	Dim Text(3)

	Set Rs = Server.CreateObject("adodb.recordset")
	Rs.Open "select ClassName,ParentPath from NT_ClassName where ID="&ClassID,Conn,1,1
	If Not Rs.Eof Then
		Text(1) = Rs(0)
		Text(2) = Rs(1)
		Rs.Close
		
		Text(3) = ""
		If InStr(Text(2),",") Then
			ParentPath = Split(Text(2),",")
			For i = 1 To Ubound(ParentPath)
				Rs.Open "Select ClassName from Nt_ClassName where ID="&ParentPath(i),Conn,1,1
				If Not Rs.Eof Then Text(3) = Text(3)&Rs(0)&char
				Rs.Close
			Next
		End If
		If Text(3)<>"" Then
			GetLongClassName = Text(3)&Text(1)
		Else
			GetLongClassName = Text(1)
		End If
	Else
		Rs.Close
		GetLongClassName = ""
	End If
	Set Rs = Nothing
End Function

Public Function GetSpecialName(SpecialId)
	Dim Rs
	Set Rs = Server.CreateObject("adodb.recordset")
	Rs.Open "Select SpecialName From Nt_Special where Id="&SpecialId,Conn,1,1
	If Not(Rs.eof Or Rs.bof) Then
		GetSpecialName = Rs(0)
	Else
		GetSpecialName = ""
	End If
	Rs.Close
	Set Rs = Nothing
End Function
%>